1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
#include "PR/R4300.h"
#include "sys/asm.h"
#include "sys/regdef.h"
.text
LEAF(osInvalICache)
/* If the amount to invalidate is less than or equal to 0, return immediately */
blez a1, 2f
/*
* If the amount to invalidate is as large as or larger than
* the instruction cache size, invalidate all
*/
li t3, ICACHE_SIZE
bgeu a1, t3, 3f
/*
* ensure end address does not wrap around and end up smaller
* than the start address
*/
move t0, a0
addu t1, a0, a1
bgeu t0, t1, 2f
/* Mask and subtract to align to cache line */
addiu t1, t1, -ICACHE_LINESIZE
andi t2, t0, ICACHE_LINEMASK
subu t0, t0, t2
1:
CACHE( (C_HINV | CACH_PI), (t0))
.set noreorder
bltu t0, t1, 1b
addiu t0, t0, ICACHE_LINESIZE
.set reorder
2:
jr ra
3:
li t0, K0BASE
addu t1, t0, t3
addiu t1, t1, -ICACHE_LINESIZE
4:
CACHE( (C_IINV | CACH_PI), (t0))
.set noreorder
bltu t0, t1, 4b
addiu t0, t0, ICACHE_LINESIZE
.set reorder
jr ra
END(osInvalICache)
|
